Function Perft(isRoot:boolean;depth:integer; var Board:Tboard):int64;
// Процедура перфоманс теста. Gринимает на вход позицию и глубину, возвращает количество перебранных легальных ходов. Рекурсивно вызывает саму себя
var
   Movelist : TMovelist;
   Undo:TUndo;
   nodes:int64;
   i,nps,cnt:integer;
   Pins : int64;
   isEasyPass : boolean;
begin
  if isRoot then begin
    timer:=now; // Если мы в корневой  позиции, то стратуем таймер.
    ply:=0;
    old_nodes:=0;
    cummulative_nodes:=0;
  end;
  nodes:=0;
  Pins:=FindPins(Board);
  GeneratePseudoMoves(AllMoves,Board,MoveList);  // генерируем все псевдолегальные ходы
  for i:=1 to MoveList[0] do   // Цикл ходов
    begin
      isEasyPass:=EasyPass(Pins,MoveList[i],Board);
      MakeMove(Movelist[i],Board,Undo);//  Делаем ход на доске
      if  isEasyPass or (not isAttackedBySide(Board.King[-Board.SideToMove],Board.SideToMove,Board)) then
        begin
         // Если король после сделанного хода не остался под шахом (ход был легальный), то идем на глубину ниже
          if depth>1
           then begin
              Inc(ply);
              nodes:=nodes+Perft(false,depth-1,Board);
              Dec(ply);
           end
           else inc(nodes);  // Если это уже листья дерева, то просто подсчитываем сколько их, легальных.
           if (ply=0) then  begin
                old_nodes:=nodes - cummulative_nodes;
                cummulative_nodes:=cummulative_nodes + old_nodes;
                writeln(StringMove(Movelist[i])+Format(' nodes=%u',[old_nodes]));
                end;
           end;
       UnMakeMove(Undo,Board); // Возвращаем ход
    end;
  // Если мы закончили перебор из корневой позиции, то считаем время и выводим статистику
   If isRoot then
    begin
     cnt:=MillisecondsBetween(timer,now);
     if cnt<>0
      then nps:=(nodes*1000) div cnt
      else nps:=nodes;
     writeln('Perft ',depth,' - ',nodes,' nodes. At ',cnt,' msec.',nps,' nodes per second');
    end;
  Result:=nodes;
end;

Function Perft(isRoot:boolean;depth:integer; var Board:Tboard):int64;
// Процедура перфоманс теста. Gринимает на вход позицию и глубину, возвращает количество перебранных легальных ходов. Рекурсивно вызывает саму себя
var
   Movelist : TMovelist;
   Undo:TUndo;
   //nodes:int64;
   i,nps,cnt:integer;
   Pins : int64;
   isEasyPass : boolean;
begin
  if isRoot then begin
    timer:=now; // Если мы в корневой  позиции, то стратуем таймер.
    ply:=0;
    old_nodes:=0;
    cummulative_nodes:=0;
    total_nodes:=0;
    EasyPass_nodes:=0;
  end;
     if (depth = 0) then begin
      Inc(total_nodes);
      exit;
     end;
  Pins:=FindPins(Board);
  //шах ли нам? Ход еще не сделан - очередь хода наша
  Board.isoncheck:=isAttackedBySide(Board.King[Board.SideToMove],-Board.SideToMove,Board);
  GeneratePseudoMoves(AllMoves,Board,MoveList);  // генерируем все псевдолегальные ходы
  for i:=1 to MoveList[0] do   // Цикл ходов
    begin
      //для проверки функции FindPins
      isEasyPass:=EasyPass(Pins,MoveList[i],Board);
      //для проверки, работает ли isEasyPass
      if isEasyPass then Inc(EasyPass_nodes);
      MakeMove(Movelist[i],Board,Undo);//  Делаем ход на доске
      if isEasyPass or (not isAttackedBySide(Board.King[-Board.SideToMove],Board.SideToMove,Board)) then
        begin
         // Если король после сделанного хода не остался под шахом (ход был легальный), то идем на глубину ниже
              Inc(ply);
              Perft(false,depth-1,Board);
              Dec(ply);
        end;
      UnMakeMove(Undo,Board); // Возвращаем ход
      if (ply=0) then  begin
        old_nodes:=total_nodes - cummulative_nodes;
        cummulative_nodes:=cummulative_nodes + old_nodes;
        //Если не нужна статистика после каждого хода то отключаем
        //writeln(StringMove(Movelist[i])+Format(' nodes=%u',[old_nodes]));
      end;
     end;
  // Если мы закончили перебор из корневой позиции, то считаем время и выводим статистику
   If isRoot then
    begin
     cnt:=MillisecondsBetween(timer,now);
     if cnt<>0
      then nps:=(total_nodes*1000) div cnt
      else nps:=total_nodes;
     writeln('Perft ',depth,' - '+Format('%u',[total_nodes]),' nodes. At ',cnt,' msec.',nps,' nodes per second');
     writeln(Format('EasyPass_nodes=%u',[EasyPass_nodes]));
    end;
  Result:=total_nodes;
end;

Function FindPins(var Board:Tboard):int64;
// Функция возвращает битборд связанных фигур за сторону чья очередь хода.
var
  i,k,n: integer;
  temp,bb:UInt64;
  tp,tp1:integer;
  square:TBitBoard_squares;
begin
 if Board.isoncheck then
    // Если мы под шахом то возвращем битборд полной доски - проверять будем все ходящие наши фигуры.
     begin
       result:=-1;
       exit;
     end;
 result:=$0;
  //клетка нашего короля
  square:=TBitBoard_squares(MailBox[Board.King[Board.SideToMove]]);
  //находим на лучах фигуры противника
  for i := 1 to 8 do  begin
    //из square  прводим поочереди лучи до края доски
    //находим все клетки с фигурами противника на луче
    temp:=LineU64[i,ord(square)] and Board.Occupancy[-Board.SideToMove];
    if temp=0 then continue;
    //находим первый блокирующий бит (в зависимости от направления старший или младший бит)
    k:=StopBit[i and 1](temp);
    //определяем какая это фигура противника
    tp:=abs(Board.Squares[Decoder[k]]);
    if (tp=pawn) or (tp=knight)  or (tp=king) then  continue;
    //определяем, какая из дальнобойных фигур (слон или ладья или ферзь) может атаковать из k в square
    //BetweenPS[sq,square] - таблица (слон или ладья - может атаковать из k в square )
    tp1:=BetweenPS[square,TBitBoard_squares(k)];
    if (tp=tp1) or (tp=queen) then begin
    //слон или ладья или ферзь - атакует из k в square
      //если есть наша одна фигура на луче атаки
      bb:=Between[TBitBoard_squares(k),square] and Board.Occupancy[Board.SideToMove];
      if bb<>0 then
        n:=BitCount(bb) // 64 версия
        else continue;
      if n=1 then begin
         //Запоминаем потенциально связанную фигуру
         result:=result or bb;
      end;
    end;
  end;
end;

Function EasyPass(Pins : int64;move:Tmove;var Board:TBoard):boolean;
// Функция проверяет : можем ли мы избежать долгой проверки хода на легальность. Если нам нет шаха и  фигура, которая ходит не король (включая рокировку) и не связана, то ход легальный!
// Вызывается всегда ДО того как ход будет сделан на доске.
var
  from,piese : integer;
begin
  Result:=True;
  from:=move and 63;
  piese:=Board.Squares[Decoder[from]];
  //для оригинальной FindPins
  //if (Board.isoncheck) or (abs(piese)=king) or ((Pins and (1 shl from))<>0) then Result:=False;
  //для модифицированной FindPins
  if (Board.isoncheck) or (abs(piese)=king) or ((Pins and MaskOneBit[from])<>0) then Result:=False;
end;