// Генерируем все псевдолегальные (без проверки на "под шахом") ходы за сторону, чья очередь хода. Сохраняем все полученные ходы в списке.
var
  i,Pcolor: integer;
begin
  MoveList[0]:=0; // инициализируем список
  for i:=11 to 88 do  // Просматриваем всю доску
    if (Mailbox[i]>=0) then     // Смотрим что стоит на легальном поле
     begin
        PColor:=PieseColor(i,Board);
        if Pcolor=Board.SideToMove then // если стоит фигура нашего цвета то генерируем ходы в зависимости от ее типа
          begin
            if Board.Squares[i]=Pawn*Pcolor   then GeneratePawnMoves(i,TypMoves,Board,Movelist) else
                                                   GenerateBBMoves(i,TypMoves,Board,Movelist);
          end;
     end;
  if TypMoves=AllMoves then GenerateCastles(Board,Movelist); //  рокировки
end;

Procedure GenerateBBMoves(Sq:integer;TypMoves:integer;var Board:Tboard;var MoveList:TMovelist);
// Генерируем псевдолегальные (без проверки на шах) ходы фигур(дальнобойные, конь и король)  с поля SQ (цвет фигуры определяется тем чья очередь хода на доске)
// На входе поле фигуры, тип ходов, которые мы хотим генерировать, доска и список  куда сохраняем ходы.
var
   i,newsq,PColor : integer;
   bb: Uint64;
begin
  bb:=$0;
  //атаки фигур
  bb:=bb or (AttacksTable[Board.Squares[sq]](TBitBoard_squares(MailBox[sq]),Board.Occupancy[white] or Board.Occupancy[black])and not Board.Occupancy[Board.SideToMove]);
  while bb<>0 do begin
    newsq:=Decoder[BitScanForward(bb)];
          // Если тип ходов, которые мы генируем "только активные" то проверяем чтобы мы обязательно взяли чужую фигуру
          // Для  "все ходы" - сохраняем ход без такой проверки
          PColor:=PieseColor(newsq,Board);
          if (Pcolor<>Board.SideToMove) and ((TypMoves=AllMoves) or (Pcolor=-Board.SideToMove)) then
          // Цвет чужой фигуры имеет противоположный знак. У нас 1 - белые, -1 - черные.
            begin
              inc(Movelist[0]); // Счетчик ходов в списке
              Movelist[MoveList[0]]:=MailBox[sq] or (MailBox[newsq] shl 6); // Сохраняем  ход в нашей принятой кодировке, смещая поле "куда" на 6 бит влево
            end;
    bb:=bb and (bb-1);
  end;

end;

//функция всех атак
Function isAttackedbySide(sq:integer;color:integer;var Board:TBoard):boolean;
// Процедура определяет атаковано ли поле SQ за сторону цвета сolor.
var
i:integer;
bb,occupancy:UInt64;
square:TBitBoard_squares;
begin
 result:=true;
 //перебираем все фигуры цвета color
 bb:=Board.Occupancy[color];
 //все фигуры
 occupancy:=Board.Occupancy[white] or Board.Occupancy[black];
 while bb<>0 do begin
   i:=BitScanForward(bb);
   //клетка где стоит фигура
   square:=TBitBoard_squares(i);
   //если фигура атакует клетку sq то выходим
   if (AttacksTable[Board.Squares[Decoder[i]]](square,occupancy) and MaskOneBit[MailBox[sq]])<>0 then exit;
   bb:=bb and (bb-1);
 end;
 result:=false;
end;

Function isAttackedbySide(sq:integer;color:integer;var Board:TBoard):boolean;
// Процедура определяет атаковано ли поле SQ за сторону цвета сolor.
var
temp:UInt64;
count,tp,tp1:integer;
occupancy:UInt64;
square,square1:TBitBoard_squares;
begin
  //все фигуры
  occupancy:=Board.Occupancy[white] or Board.Occupancy[black];
  //атакуемая клетка
  square:=TBitBoard_squares(MailBox[sq]);
  //ставим суперфигуру на square (ферзь + конь)
  //находим все клетки с фигурами на occupancy, атакуемые суперфигурой
  temp:=(get_rook_attacks(square,occupancy) or get_bishop_attacks(square,occupancy) or knight_attacks[square]) and occupancy ;
  result:=true;
  //перебераем все клетки с фигурами, атакуемые суперфигурой
  for count:=0 to BitCount(temp)-1 do begin // 64 версия
      // get LS1B index
      // находим первую клетку
      square1:=TBitBoard_squares(BitScanForward(temp));// 64 версия
      // pop LS1B
      // исключаем первую клеку  из temp
      temp:=temp and (temp-1);
      //выбираем только клетки с фигурами цвета оппонента
      if PieseColor(Decoder[ord(square1)],Board)<>color then continue;
      //определяем фигуру на этой клетке
      tp:=abs(Board.Squares[Decoder[ord(square1)]]);
      //определяем, какая из фигур (слон или ладья или конь) может атаковать из  sq в square
      //BetweenPS[sq,square] - таблица (слон или ладья или конь - может атаковать из sq в square )
      tp1:=BetweenPS[square,square1];
      if (tp=tp1) or ((tp1<>knight) and (tp=queen)) then begin
         //слон или ладья или конь или ферзь - атакует из square1 в square
         exit;
      end;
      //атаки фигуры tp(король или пешка) из клетки из square1 в square
         if (AttacksTable[Board.Squares[Decoder[ord(square1)]]](square1,occupancy) and MaskOneBit[MailBox[sq]])<>0 then exit;
  end;
result:=false;
end;

Function getSmallestAttacker(sq:integer;var from:integer;var Board:TBoard):integer;
// Возвращает фигуру минимальной стоимости за сторону, чья очередь хода на поле SQ  и поле на котором она стоит
var
temp:UInt64;
count,tp,tp1:integer;
occupancy:UInt64;
square,square1:TBitBoard_squares;
//[фигура,позиция=[фигура]+6]
sort_tp:array[1..12] of integer;
begin
  Result:=Empty;    // По умолчанию мы никого не атакуем при нашей очереди хода
  from:=-1;         // Невозможное поле где стоит атакующая фигура
  FillChar(sort_tp, SizeOf(sort_tp), 0);
  //все фигуры
  occupancy:=Board.Occupancy[white] or Board.Occupancy[black];
  //атакуемая клетка
  square:=TBitBoard_squares(MailBox[sq]);
  //ставим суперфигуру на square (ферзь + конь)
  //находим все клетки с фигурами на occupancy, атакуемые суперфигурой
  temp:=(get_rook_attacks(square,occupancy) or get_bishop_attacks(square,occupancy) or knight_attacks[square]) and occupancy ;
  //перебераем все клетки с фигурами, атакуемые суперфигурой
  for count:=0 to BitCount(temp)-1 do begin // 64 версия
      // get LS1B index
      // находим первую клетку
      square1:=TBitBoard_squares(BitScanForward(temp));// 64 версия
      // pop LS1B
      // исключаем первую клеку  из temp
      temp:=temp and (temp-1);
      //выбираем только клетки с фигурами своего цвета
      if PieseColor(Decoder[ord(square1)],Board)<>Board.SideToMove then continue;
      //определяем фигуру на этой клетке
      tp:=abs(Board.Squares[Decoder[ord(square1)]]);
      //определяем, какая из фигур (слон или ладья или конь) может атаковать из  sq в square
      //BetweenPS[sq,square] - таблица (слон или ладья или конь - может атаковать из sq в square )
      tp1:=BetweenPS[square,square1];
      if (tp=tp1) or ((tp1<>knight) and (tp=queen)) then begin
        //слон или ладья или конь или ферзь - атакует из square1 в square
       sort_tp[tp]:=tp;
       sort_tp[tp+6]:=Decoder[ord(square1)];
       continue;
      end;
      //атаки фигуры tp(король или пешка) из клетки из square1 в square
      if (AttacksTable[Board.Squares[Decoder[ord(square1)]]](square1,occupancy) and MaskOneBit[MailBox[sq]])<>0 then
      begin
        //пешка или король - атакует из square1 в square
       sort_tp[tp]:=tp;
       sort_tp[tp+6]:=Decoder[ord(square1)];
       if tp=1 then break;
       continue;
      end;
  end;
  for count:=1 to 6 do begin
     if sort_tp[count]<>0 then begin
       Result:=sort_tp[count];
       from:=sort_tp[count+6];
       exit;
     end;
  end;
end;

Function Perft(isRoot:boolean;depth:integer; var Board:Tboard):int64;
// Процедура перфоманс теста. принимает на вход позицию и глубину, возвращает количество перебранных легальных ходов. Рекурсивно вызывает саму себя
var
   Movelist : TMovelist;
   Undo:TUndo;
   nodes:int64;
   i,nps,cnt:integer;
   Pins : int64;
   isEasyPass : boolean;
begin
  if isRoot then timer:=now; // Если мы в корневой  позиции, то стратуем таймер.
  nodes:=0;
  Pins:=FindPins(Board);
  GeneratePseudoMoves(AllMoves,Board,MoveList);  // генерируем все псевдолегальные ходы
  for i:=1 to MoveList[0] do   // Цикл ходов
    begin
      isEasyPass:=EasyPass(Pins,MoveList[i],Board);
      MakeMove(Movelist[i],Board,Undo);//  Делаем ход на доске
      if  isEasyPass or  (not isAttackedBySide(Board.King[-Board.SideToMove],Board.SideToMove,Board)) then
        begin
         // Если король после сделанного хода не остался под шахом (ход был легальный), то идем на глубину ниже
          if depth>1
           then nodes:=nodes+Perft(false,depth-1,Board)
           else inc(nodes);  // Если это уже листья дерева, то просто подсчитываем сколько их, легальных.
        end;
       UnMakeMove(Undo,Board); // Возвращаем ход
    end;
  // Если мы закончили перебор из корневой позиции, то считаем время и выводим статистику
   If isRoot then
    begin
     cnt:=MillisecondsBetween(timer,now);
     if cnt<>0
      then nps:=(nodes*1000) div cnt
      else nps:=nodes;
     writeln('Perft ',depth,' - ',nodes,' nodes. At ',cnt,' msec.',nps,' nodes per second');
    end;
  Result:=nodes;
end;